\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\* PROC FREQ \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

/\*Retrieving ODS Table names\*/

ods trace on;

proc freq data=sashelp.heart;

table Status DeathCause Sex Chol\_Status BP\_Status Weight\_Status Smoking\_Status;

run;

ods trace off;

/\*Creating output dataset\*/

ods output OneWayFreqs=OneWayFreqs/\*(drop=F\_Status F\_DeathCause F\_Sex F\_Chol\_Status F\_BP\_Status F\_Weight\_Status F\_Smoking\_Status)\*/;

proc freq data=sashelp.heart;

table Status DeathCause Sex Chol\_Status BP\_Status Weight\_Status Smoking\_Status / MISSPRINT; /\*Could use MISSING or leave blank\*/

run;

/\*View output dataset\*/

proc print data=OneWayFreqs;

run;

/\*Restructure OneWayFreqs\*/

/\*VarValue is only used when numeric values are entered for categorical variables and labels are assigned\*/

data OneWayFreqs (KEEP = VarName VarFmt VarLabel VarValue frequency percent cumfrequency cumpercent);

length VarName $32

VarLabel $256

VarFmt $256

VarValue 8;

set OneWayFreqs;

array vars {\*} Status DeathCause Sex Chol\_Status BP\_Status Weight\_Status Smoking\_Status;

VarName=SCAN(table,2,' ');

do i = 1 to DIM(vars);

if UPCASE(VarName)=UPCASE(VNAME(vars(i))) then do;

VarFmt =VVALUE(vars(i));

VarLabel =VLABEL(vars(i));

VarValue =vars(i);

return;

end;

end;

run;

/\*View output dataset\*/

proc print data=OneWayFreqs;

run;

/\*Adding labels\*/

data OneWayFreqs;

set OneWayFreqs;

LABEL VarName="Variable Name"

VarLabel="Variable"

VarFmt="Categories"

VarValue="Value";

if VarFmt="" then VarFmt="Missing";

run;

/\*Print Table\*/

proc print data=OneWayFreqs noobs label;

var VarLabel VarFmt frequency percent;

run;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\* PROC MEANS \*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

/\*proc means generates a nice looking table but when saved as an .rtf all the variables are in one cell\*/

proc means data=sashelp.heart maxdec=2;

var AgeCHDdiag AgeAtStart Height Weight Diastolic Systolic MRW AgeAtDeath Cholesterol;

run;

/\*Output results to a dataset\*/

/\*ods output summary=var\_means;---DOES NOT WORK\*/

proc means data=sashelp.heart maxdec=2;

var AgeCHDdiag AgeAtStart Height Weight Diastolic Systolic MRW AgeAtDeath Cholesterol;

output out=var\_means;

run;

/\*View output dataset\*/

proc print data=var\_means;

run;

/\*Dropping \_TYPE\_ and \_FREQ\_\*/

proc means data=sashelp.heart maxdec=2;

var AgeCHDdiag AgeAtStart Height Weight Diastolic Systolic MRW AgeAtDeath Cholesterol;

output out=var\_means(drop=\_FREQ\_ \_TYPE\_);

run;

/\*Transpose dataset\*/

proc transpose data=var\_means out=trans\_mean(rename=(\_NAME\_=VarName \_LABEL\_=VarLabel));

id \_STAT\_;

run;

/\*View output dataset\*/

proc print data=trans\_mean;

run;

/\*Even if you specify additional stats (e.g. median) they won't be included in the output dataset\*/

proc means data=sashelp.heart maxdec=2 n mean std min max median;

var AgeCHDdiag AgeAtStart Height Weight Diastolic Systolic MRW AgeAtDeath Cholesterol;

output out=var\_means(drop=\_FREQ\_ \_TYPE\_);

run;

/\*View output dataset\*/

proc print data=var\_means;

run;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*

\*\* PROC UNIVARIATE \*\*\*\*\*\*\*\*\*\*\*

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

/\*Creating output datasets\*/

ods output BasicMeasures=BasicMeasures;

proc univariate data=sashelp.heart;

var AgeCHDdiag AgeAtStart Height Weight Diastolic Systolic MRW AgeAtDeath Cholesterol;

run;

/\*View output dataset\*/

proc print data=BasicMeasures;

run;

proc sort data=BasicMeasures;

by VarName;

run;

/\*Restructuring BasicMeasures to create a composite summary dataset with one row per variable\*/

data BasicMeasures (keep = VarName Median);

length VarName $32;

set BasicMeasures;

by VarName;

if LocMeasure="Median" then Median=LocValue;

if LAST.VarName then

output BasicMeasures;

retain Median;

run;

/\*View output dataset\*/

proc print data=BasicMeasures;

run;

proc sort data=trans\_mean;

by VarName;

run;

/\*Create final composite dataset\*/

data UnivariateStats;

length VarName $32;

merge Trans\_Mean BasicMeasures ;

by VarName;

run;

/\*View output dataset\*/

proc print data=UnivariateStats;

run;

/\*Adding Labels\*/

data UnivariateStats;

set UnivariateStats;

LABEL VarName="Variable Name"

VarLabel="Variable"

MIN="Min"

MAX="Max"

MEAN="Mean"

STD="Standard Deviation";

if VarLabel="" then VarLabel=VarName;

run;

/\*Print Table\*/

proc print data=UnivariateStats noobs label;

var VarLabel n median mean std ;

run;