\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* Quick and dirty.sas \*;

\* Program to demonstrate use of macros to create semi-finished report describing \*;

\* dataset contents (including limited summary measures). Developed for \*;

\* presentation at Univ of Iowa SAS User Group spring 2014 meeting. \*;

\* \*;

\* THERE IS NO WARRANTY FOR THE PROGRAM OF ANY KIND, EITHER EXPRESSED OR IMPLIED. \*;

\* THE ENTIRE RISK AS TO THE QUALITY AND PERFORMANCE OF THE PROGRAM IS WITH YOU \*;

\* \*;

\* There is no fee for using, modifying, stealing, or otherwise appropriating any \*;

\* part of the program EXCEPT if it is useful (in any way) for work leading to a \*;

\* Nobel prize, whereupon the winner agrees to provide FU with a shrubbery \*;

\* (One that looks nice... and is not too expensive) \*;

\* \*;

\* fu <4/7/2014> \*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

options nocenter ls=120;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* create working dataset \*;

\* do any necessary data cleaning \*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

data demo;

 set sashelp.cars;

run;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* build three reporting macros \*;

\* fewcats - for freq counts \*;

\* manycats - vars with many response cats \*;

\* nums - for min/max report \*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

%macro fewcats ( dsn , var , lbl );

 ods listing close;

 ods output onewayfreqs=ot1;

 proc freq data=&dsn;

 tables &var / missing;

 run;

 ods listing;

 data work1(keep=vname n\_resp nmiss outs ct lbl);

 set ot1 end=eof;

 length lbl $ 40;

 lbl="&lbl";

 retain nmiss n\_resp;

 length vname $ 30 outs $ 40;

 vname=substr(table,7);

 if \_n\_=1 then do;

 n\_resp=frequency/(percent/100);

 if missing(&var) then n\_resp=n\_resp-frequency;

 end;

 if missing(&var) then nmiss=frequency;

 else do;

 outs=&var;

 ct=frequency;

 output;

 end;

 run;

 proc append base=keeper data=work1;

 run;

%mend;

%macro manycats ( dsn , var , lbl );

 proc sort data=&dsn out=work0(keep=&var);

 by &var;

 run;

 data work1(keep=vname n\_resp nmiss outs ct lbl);

 set work0 end=eof;

 by &var;

 retain nmiss n\_resp min\_ct max\_ct tcount rcount;

 if \_n\_=1 then do;

 nmiss=0; n\_resp=0; min\_ct=1000000; max\_ct=0; rcount=0;

 end;

 if missing(&var) then nmiss=nmiss+1;

 else n\_resp=n\_resp+1;

 if first.&var then do;

 rcount=rcount+1;

 tcount=0;

 end;

 tcount=tcount+1;

 ct=.;

 if last.&var and not missing(&var) then do;

 if tcount>max\_ct then max\_ct=tcount;

 if tcount<min\_ct then min\_ct=tcount;

 end;

 length lbl $ 40;

 lbl="&lbl";

 retain nmiss n\_resp;

 length vname $ 30 outs $ 40;

 if eof then do;

 vname="&var";

 outs="Unique resp: " || put(rcount, 6.); output;

 outs="Max. appear: " || put(max\_ct, 6.); output;

 outs="Min. appear: " || put(min\_ct, 6.); output;

 end;

 run;

 proc append base=keeper data=work1;

 run;

%mend;

%macro nums ( dsn , var , fmt , lbl );

 ods listing close;

 ods output onewayfreqs=ot1;

 proc freq data=&dsn;

 tables &var / missing;

 run;

 ods listing;

 data work1(keep=vname n\_resp nmiss outs ct lbl);

 set ot1 end=eof;

 length lbl $ 40;

 lbl="&lbl";

 ct=.;

 retain flag nmiss n\_resp;

 length vname $ 30 outs $ 40;

 vname=substr(table,7);

 if \_n\_=1 then do;

 n\_resp=frequency/(percent/100);

 if &var=. then n\_resp=n\_resp-frequency;

 flag='n';

 end;

 if &var=. then nmiss=frequency;

 else do;

 if flag='n' then do;

 outs="Min: " || put(&var, &fmt);

 flag='y';

 output;

 end;

 end;

 if eof then do;

 outs="Max: " || put(&var, &fmt);

 flag='y';

 output;

 end;

 run;

 proc append base=keeper data=work1;

 run;

%mend;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* prep and call the reporting macros \*;

\* start by emptying out 'keeper' dataset \*;

\* call macro appropriate for each variable\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

proc datasets;

 delete keeper;

quit;

%fewcats ( demo , origin , Continent of origin );

%manycats ( demo , make , Automobile manufacturer );

%manycats ( demo , model , Model name );

%fewcats ( demo , type , Body type );

%nums ( demo , msrp , dollar8. , MSRP );

%nums ( demo , weight , best12. , GVW );

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* 'buff' the final keeper dataset: \*;

\* assign an "order" number to the variables \*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

data keeperx;

 set keeper;

if nmiss=. then nmiss=0;

retain oldvar count;

if \_n\_=1 then do;

 oldvar=vname;

 count=1;

end;

if vname ne oldvar then do;

 oldvar=vname;

 count=count+1;

end;

run;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

\* write the report \*;

\* set necessary general and ODS options \*;

\* make sure your file destination (i.e. \*;

\* path and filename are set correctly) \*;

\* REPORT provides some nice format options\*;

\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*;

title ' '; \* get rid of 'The SAS System';

options nodate nonumber; \* get rid of date and page number;

ods noptitle; \* get rid of procedure title;

ods listing close;

ods rtf file='c:\junk\QandD demo.rtf' bodytitle style=minimal; \* put title in doc body;

options missing=' ';

proc report data=keeperx nowd;

 column count vname lbl n\_resp nmiss outs ct;

 define count / order;

 define vname / order;

 define lbl / order;

 define n\_resp / order;

 define nmiss / order;

 compute after vname;

 line ' ';

 endcomp;

 format outs $40. n\_resp nmiss comma10. ;

 label

 count='#'

 vname='Variable'

 lbl='Label'

 n\_resp='# Resp'

 nmiss='# Missing'

 outs='Summary output'

 ct='Count';

 title 'Quick and Dirty Demo Report';

run;

ods rtf close;

ods listing;